Rules for integrands of the form  u (((a+b ArcCosh[c x]))^n)

1.  ∫(((d+e x))^m) (((a+b ArcCosh[c x]))^n)dx

1.  ∫(((d+e x))^m) (((a+b ArcCosh[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

1:  ∫((((a+b ArcCosh[c x]))^n)/(d+e x))dx

Derivation: Integration by substitution

Basis: (1/(d+e x))==Subst[((Sinh[x])/(c d+e Cosh[x])),x,ArcCosh[c x]](∂_x)ArcCosh[c x]

Note: (((((a+b x))^n) Sinh[x])/(c d+e Cosh[x])) is not integrable unless n∈(SuperPlus[ℤ]).

Rule: If  n∈(SuperPlus[ℤ]), then

∫((((a+b ArcCosh[c x]))^n)/(d+e x))dx  ⟶  Subst[∫(((((a+b x))^n) Sinh[x])/(c d+e Cosh[x]))dx,x,ArcCosh[c x]]

Program code:

Int[(a_.+b_.*ArcCosh[c_.*x_])^n_./(d_.+e_.*x_),x_Symbol] :=
  Subst[Int[(a+b*x)^n*Sinh[x]/(c*d+e*Cosh[x]),x],x,ArcCosh[c*x]] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[n,0]

2:  ∫(((d+e x))^m)(((a+b ArcCosh[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ m≠-1

Reference: G&R 2.832, CRC 454, A&S 4.4.67

Derivation: Integration by parts

Basis: (((d+e x))^m)==(∂_x)((((d+e x))^(m+1))/(e (m+1)))

Basis: (∂_x)(((a+b ArcCosh[c x]))^n)==((b c n (((a+b ArcCosh[c x]))^(n-1)))/((Sqrt[-1+c x]) (Sqrt[1+c x])))

Rule: If  n∈(SuperPlus[ℤ])∧ m≠-1, then

∫(((d+e x))^m)(((a+b ArcCosh[c x]))^n)dx  ⟶  (((((d+e x))^(m+1))(((a+b ArcCosh[c x]))^n))/(e(m+1)))-((b c n)/(e(m+1)))∫(((((d+e x))^(m+1))(((a+b ArcCosh[c x]))^(n-1)))/((Sqrt[-1+c x]) (Sqrt[1+c x])))dx

Program code:

Int[(d_.+e_.*x_)^m_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  (d+e*x)^(m+1)*(a+b*ArcCosh[c*x])^n/(e*(m+1)) - 
  b*c*n/(e*(m+1))*Int[(d+e*x)^(m+1)*(a+b*ArcCosh[c*x])^(n-1)/(Sqrt[-1+c*x]*Sqrt[1+c*x]),x] /;
FreeQ[{a,b,c,d,e,m},x] && IGtQ[n,0] && NeQ[m,-1]

2.  ∫(((d+e x))^m) (((a+b ArcCosh[c x]))^n)dx  when  m∈(SuperPlus[ℤ])

1:  ∫(((d+e x))^m)(((a+b ArcCosh[c x]))^n)dx  when  m∈(SuperPlus[ℤ])∧ n<-1

Derivation: Algebraic expansion

Rule: If  m∈(SuperPlus[ℤ])∧ n<-1, then

∫(((d+e x))^m)(((a+b ArcCosh[c x]))^n)dx  ⟶  ∫ExpandIntegrand[(((d+e x))^m)(((a+b ArcCosh[c x]))^n),x]dx

Program code:

Int[(d_+e_.*x_)^m_.*(a_.+b_.*ArcCosh[c_.*x_])^n_,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x)^m*(a+b*ArcCosh[c*x])^n,x],x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[m,0] && LtQ[n,-1]

2:  ∫(((d+e x))^m)(((a+b ArcCosh[c x]))^n)dx  when  m∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: F[x]==(1/c) Subst[Sinh[x] F[((Cosh[x])/c)],x,ArcCosh[c x]] (∂_x)ArcCosh[c x]

Basis: If  m∈ℤ, then (((d+e x))^m)==(1/(c^(m+1))) Subst[Sinh[x] (((c d+e Cosh[x]))^m),x,ArcCosh[c x]] (∂_x)ArcCosh[c x]

Note: If  m∈(SuperPlus[ℤ]), then (((a+b x))^n) Sinh[x] (((c d+e Cosh[x]))^m) is integrable in closed-form.

Rule: If  m∈(SuperPlus[ℤ]), then

∫(((d+e x))^m)(((a+b ArcCosh[c x]))^n)dx  ⟶  (1/(c^(m+1))) Subst[∫(((a+b x))^n) Sinh[x] (((c d+e Cosh[x]))^m)dx,x,ArcCosh[c x]]

Program code:

Int[(d_.+e_.*x_)^m_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  1/c^(m+1)*Subst[Int[(a+b*x)^n*Sinh[x]*(c*d+e*Cosh[x])^m,x],x,ArcCosh[c*x]] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[m,0]

2.  ∫(Subscript[P, x]) (((a+b ArcCosh[c x]))^n)dx

1:  ∫(Subscript[P, x]) (a+b ArcCosh[c x])dx

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)(a+b ArcCosh[c x])==((b c)/((Sqrt[-1+c x]) (Sqrt[1+c x])))

Basis: (∂_x)((Sqrt[1-(c^2) (x^2)])/((Sqrt[-1+c x]) (Sqrt[1+c x])))==0

Rule: Let  u->∫(Subscript[P, x])dx, then

∫(Subscript[P, x]) (a+b ArcCosh[c x])dx  ⟶  u(a+b ArcCosh[c x])-b c∫(u/((Sqrt[-1+c x]) (Sqrt[1+c x])))dx
  ⟶  u(a+b ArcCosh[c x])-((b c (Sqrt[1-(c^2) (x^2)]))/((Sqrt[-1+c x]) (Sqrt[1+c x])))∫(u/(Sqrt[1-(c^2) (x^2)]))dx

Program code:

Int[Px_*(a_.+b_.*ArcCosh[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[ExpandExpression[Px,x],x]},  
  Dist[a+b*ArcCosh[c*x],u,x] - 
  b*c*Sqrt[1-c^2*x^2]/(Sqrt[-1+c*x]*Sqrt[1+c*x])*Int[SimplifyIntegrand[u/Sqrt[1-c^2*x^2],x],x]] /;
FreeQ[{a,b,c},x] && PolyQ[Px,x]

x:  ∫(Subscript[P, x])(((a+b ArcCosh[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)(((a+b ArcCosh[c x]))^n)==((b c n (((a+b ArcCosh[c x]))^(n-1)))/((Sqrt[-1+c x]) (Sqrt[1+c x])))

Basis: (∂_x)((Sqrt[1-(c^2) (x^2)])/((Sqrt[-1+c x]) (Sqrt[1+c x])))==0

Rule: If  n∈(SuperPlus[ℤ]), let  u->∫(Subscript[P, x])dx, then

∫(Subscript[P, x])(((a+b ArcCosh[c x]))^n)dx  ⟶  u(((a+b ArcCosh[c x]))^n)-b c n∫((u (((a+b ArcCosh[c x]))^(n-1)))/((Sqrt[-1+c x]) (Sqrt[1+c x])))dx
  ⟶  u(((a+b ArcCosh[c x]))^n)-((b c n (Sqrt[1-(c^2) (x^2)]))/((Sqrt[-1+c x]) (Sqrt[1+c x])))∫((u (((a+b ArcCosh[c x]))^(n-1)))/(Sqrt[1-(c^2) (x^2)]))dx

Program code:

(* Int[Px_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  With[{u=IntHide[Px,x]},  
  Dist[(a+b*ArcCosh[c*x])^n,u,x] - 
  b*c*n*Sqrt[1-c^2*x^2]/(Sqrt[-1+c*x]*Sqrt[1+c*x])*Int[SimplifyIntegrand[u*(a+b*ArcCosh[c*x])^(n-1)/Sqrt[1-c^2*x^2],x],x]] /;
FreeQ[{a,b,c},x] && PolyQ[Px,x] && IGtQ[n,0] *)

2:  ∫(Subscript[P, x])(((a+b ArcCosh[c x]))^n)dx  when  n≠1

Derivation: Algebraic expansion

Rule: If  n≠1, then

∫(Subscript[P, x])(((a+b ArcCosh[c x]))^n)dx  ⟶  ∫ExpandIntegrand[(Subscript[P, x])(((a+b ArcCosh[c x]))^n),x]dx

Program code:

Int[Px_*(a_.+b_.*ArcCosh[c_.*x_])^n_,x_Symbol] :=
  Int[ExpandIntegrand[Px*(a+b*ArcCosh[c*x])^n,x],x] /;
FreeQ[{a,b,c,n},x] && PolyQ[Px,x]

3.  ∫(Subscript[P, x]) (((d+e x))^m) (((a+b ArcCosh[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

1:  ∫(Subscript[P, x])(((d+e x))^m)(a+b ArcCosh[c x])dx

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)(a+b ArcCosh[c x])==((b c)/((Sqrt[-1+c x]) (Sqrt[1+c x])))

Basis: (∂_x)((Sqrt[1-(c^2) (x^2)])/((Sqrt[-1+c x]) (Sqrt[1+c x])))==0

Rule: Let  u->∫(Subscript[P, x])(((d+e x))^m)dx, then

∫(Subscript[P, x])(((d+e x))^m)(a+b ArcCosh[c x])dx  ⟶  u(a+b ArcCosh[c x])-b c∫(u/((Sqrt[-1+c x]) (Sqrt[1+c x])))dx
  ⟶  u (a+b ArcCosh[c x])-((b c (Sqrt[1-(c^2) (x^2)]))/((Sqrt[-1+c x]) (Sqrt[1+c x])))∫(u/(Sqrt[1-(c^2) (x^2)]))dx

Program code:

Int[Px_*(d_.+e_.*x_)^m_.*(a_.+b_.*ArcCosh[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[Px*(d+e*x)^m,x]},  
  Dist[a+b*ArcCosh[c*x],u,x] - 
  b*c*Sqrt[1-c^2*x^2]/(Sqrt[-1+c*x]*Sqrt[1+c*x])*Int[SimplifyIntegrand[u/Sqrt[1-c^2*x^2],x],x]] /;
FreeQ[{a,b,c,d,e,m},x] && PolyQ[Px,x]

2:  ∫(((f+g x))^p) (((d+e x))^m) (((a+b ArcCosh[c x]))^n)dx  when  (n|p)∈(SuperPlus[ℤ])∧ m∈(SuperMinus[ℤ])∧ m+p+1<0

Derivation: Integration by parts

Basis: (∂_x)(((a+b ArcCosh[c x]))^n)==((b c n (((a+b ArcCosh[c x]))^(n-1)))/((Sqrt[-1+c x]) (Sqrt[1+c x])))

Note: If  p∈(SuperPlus[ℤ])∧ m∈(SuperMinus[ℤ])∧ m+p+1<0, then ∫(((f+g x))^p) (((d+e x))^m)dx is a rational function.

Rule: If  (n|p)∈(SuperPlus[ℤ])∧ m∈(SuperMinus[ℤ])∧ m+p+1<0, let  u->∫(((f+g x))^p) (((d+e x))^m)dx, then

∫(((f+g x))^p) (((d+e x))^m) (((a+b ArcCosh[c x]))^n)dx  ⟶  u (((a+b ArcCosh[c x]))^n)-b c n ∫((u (((a+b ArcCosh[c x]))^(n-1)))/((Sqrt[-1+c x]) (Sqrt[1+c x])))dx

Program code:

Int[(f_.+g_.*x_)^p_.*(d_+e_.*x_)^m_*(a_.+b_.*ArcCosh[c_.*x_])^n_,x_Symbol] :=
  With[{u=IntHide[(f+g*x)^p*(d+e*x)^m,x]},  
  Dist[(a+b*ArcCosh[c*x])^n,u,x] - 
  b*c*n*Int[SimplifyIntegrand[u*(a+b*ArcCosh[c*x])^(n-1)/(Sqrt[-1+c*x]*Sqrt[1+c*x]),x],x]] /;
FreeQ[{a,b,c,d,e,f,g},x] && IGtQ[n,0] && IGtQ[p,0] && ILtQ[m,0] && LtQ[m+p+1,0]

3:  ∫(((((f+g x+h (x^2)))^p) (((a+b ArcCosh[c x]))^n))/(((d+e x))^2))dx  when  (n|p)∈(SuperPlus[ℤ])∧ e g-2 d h==0

Derivation: Integration by parts

Basis: (∂_x)(((a+b ArcCosh[c x]))^n)==((b c n (((a+b ArcCosh[c x]))^(n-1)))/((Sqrt[-1+c x]) (Sqrt[1+c x])))

Note: If  p∈(SuperPlus[ℤ])∧ e g-2 d h==0, then ∫((((f+g x+h (x^2)))^p)/(((d+e x))^2))dx is a rational function.

Rule: If  (n|p)∈(SuperPlus[ℤ])∧ e g-2 d h==0, let  u->∫((((f+g x+h (x^2)))^p)/(((d+e x))^2))dx, then

∫(((((f+g x+h (x^2)))^p) (((a+b ArcCosh[c x]))^n))/(((d+e x))^2))dx  ⟶  u (((a+b ArcCosh[c x]))^n)-b c n ∫((u (((a+b ArcCosh[c x]))^(n-1)))/((Sqrt[-1+c x]) (Sqrt[1+c x])))dx

Program code:

Int[(f_.+g_.*x_+h_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_/(d_+e_.*x_)^2,x_Symbol] :=
  With[{u=IntHide[(f+g*x+h*x^2)^p/(d+e*x)^2,x]},  
  Dist[(a+b*ArcCosh[c*x])^n,u,x] - 
  b*c*n*Int[SimplifyIntegrand[u*(a+b*ArcCosh[c*x])^(n-1)/(Sqrt[-1+c*x]*Sqrt[1+c*x]),x],x]] /;
FreeQ[{a,b,c,d,e,f,g,h},x] && IGtQ[n,0] && IGtQ[p,0] && EqQ[e*g-2*d*h,0]

4:  ∫(Subscript[P, x]) (((d+e x))^m) (((a+b ArcCosh[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ m∈ℤ

Derivation: Algebraic expansion

Rule: If  n∈(SuperPlus[ℤ])∧ m∈ℤ, then

∫(Subscript[P, x]) (((d+e x))^m) (((a+b ArcCosh[c x]))^n)dx  ⟶  ∫ExpandIntegrand[(Subscript[P, x])(((d+e x))^m) (((a+b ArcCosh[c x]))^n),x]dx

Program code:

Int[Px_*(d_+e_.*x_)^m_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[Px*(d+e*x)^m*(a+b*ArcCosh[c*x])^n,x],x] /;
FreeQ[{a,b,c,d,e},x] && PolyQ[Px,x] && IGtQ[n,0] && IntegerQ[m]

4.  ∫F[f+g x] (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ p-(1/2)∈ℤ

1:  ∫(((f+g x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ p-(1/2)∈ℤ ∧ m∈ℤ

Derivation: Piecewise constant extraction

Basis: If  (c^2) d+e==0, then (∂_x)((((d+e (x^2)))^p)/((((-1+c x))^p) (((1+c x))^p)))==0

Rule: If  (c^2) d+e==0 ∧ p-(1/2)∈ℤ ∧ m∈ℤ, then

∫(((f+g x))^m)(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  
(((((-d))^(IntPart[p])) (((d+e (x^2)))^(FracPart[p])))/((((-1+c x))^(FracPart[p])) (((1+c x))^(FracPart[p]))))∫(((f+g x))^m)(((-1+c x))^p) (((1+c x))^p)(((a+b ArcCosh[c x]))^n)dx

Program code:

Int[(f_+g_.*x_)^m_.*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  (-d)^IntPart[p]*(d+e*x^2)^FracPart[p]/((-1+c*x)^FracPart[p]*(1+c*x)^FracPart[p])*
    Int[(f+g*x)^m*(-1+c*x)^p*(1+c*x)^p*(a+b*ArcCosh[c*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,g,n},x] && EqQ[c^2*d+e,0] && IntegerQ[p-1/2] && IntegerQ[m]

2:  ∫Log[h (((f+g x))^m)] (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ p-(1/2)∈ℤ

Derivation: Piecewise constant extraction

Basis: If  (c^2) d+e==0, then (∂_x)((((d+e (x^2)))^p)/((((-1+c x))^p) (((1+c x))^p)))==0

Rule: If  (c^2) d+e==0 ∧ p-(1/2)∈ℤ, then

∫Log[h (((f+g x))^m)] (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  
(((((-d))^(IntPart[p])) (((d+e (x^2)))^(FracPart[p])))/((((-1+c x))^(FracPart[p])) (((1+c x))^(FracPart[p]))))∫Log[h (((f+g x))^m)] (((-1+c x))^p) (((1+c x))^p) (((a+b ArcCosh[c x]))^n)dx

Program code:

Int[Log[h_.*(f_.+g_.*x_)^m_.]*(d_+e_.*x_^2)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  (-d)^IntPart[p]*(d+e*x^2)^FracPart[p]/((-1+c*x)^FracPart[p]*(1+c*x)^FracPart[p])*
    Int[Log[h*(f+g*x)^m]*(-1+c*x)^p*(1+c*x)^p*(a+b*ArcCosh[c*x])^n,x] /;
FreeQ[{a,b,c,d,e,f,g,h,m,n},x] && EqQ[c^2*d+e,0] && IntegerQ[p-1/2]

5.  ∫F[f+g x] (((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  when  e1==c d1 ∧ e2==-c d2 ∧ p-(1/2)∈ℤ

1.  ∫(((f+g x))^m) (((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  when  e1==c d1 ∧ e2==-c d2 ∧ m∈ℤ ∧ p-(1/2)∈ℤ

1.  ∫(((f+g x))^m) (((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  when  e1==c d1 ∧ e2==-c d2 ∧ m∈ℤ ∧ p-(1/2)∈ℤ ∧ d1>0 ∧ d2<0

1:  ∫(((f+g x))^m) (((d1+e1 x))^p) (((d2+e2 x))^p) (a+b ArcCosh[c x])dx  when  e1==c d1 ∧ e2==-c d2 ∧ m∈(SuperPlus[ℤ])∧ p+(1/2)∈(SuperMinus[ℤ])∧ d1>0 ∧ d2<0 ∧ (m>3 ∨ m<-2 p-1)

Derivation: Integration by parts

Basis: (∂_x)(a+b ArcCosh[c x])==((b c)/((Sqrt[-1+c x]) (Sqrt[1+c x])))

Note: If  m∈ℤ ∧ p+(1/2)∈ℤ ∧ 0<m<-2 p-1, then ∫(((f+g x))^m) (((d1+e1 x))^p) (((d2+e2 x))^p)dx is an algebraic function.

Rule: If  e1==c d1 ∧ e2==-c d2 ∧ m∈(SuperPlus[ℤ])∧ p+(1/2)∈(SuperMinus[ℤ])∧ d1>0 ∧ d2<0 ∧ (m>3 ∨ m<-2 p-1), let  u->∫(((f+g x))^m) (((d1+e1 x))^p) (((d2+e2 x))^p)dx, then

∫(((f+g x))^m) (((d1+e1 x))^p) (((d2+e2 x))^p) (a+b ArcCosh[c x])dx  ⟶  u (a+b ArcCosh[c x])-b c∫(u/((Sqrt[-1+c x]) (Sqrt[1+c x])))dx

Program code:

Int[(f_+g_.*x_)^m_.*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_.+b_.*ArcCosh[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(f+g*x)^m*(d1+e1*x)^p*(d2+e2*x)^p,x]},  
  Dist[a+b*ArcCosh[c*x],u,x] - b*c*Int[Dist[1/(Sqrt[-1+c*x]*Sqrt[1+c*x]),u,x],x]] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,g},x] && EqQ[e1-c*d1,0] && EqQ[e2+c*d2,0] && IGtQ[m,0] && ILtQ[p+1/2,0] && GtQ[d1,0] && LtQ[d2,0] && 
  (GtQ[m,3] || LtQ[m,-2*p-1])

2:  ∫(((f+g x))^m) (((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  when  e1==c d1 ∧ e2==-c d2 ∧ m∈(SuperPlus[ℤ])∧ p+(1/2)∈ℤ ∧ d1>0 ∧ d2<0 ∧ n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  e1==c d1 ∧ e2==-c d2 ∧ m∈(SuperPlus[ℤ])∧ p+(1/2)∈ℤ ∧ d1>0 ∧ d2<0 ∧ n∈(SuperPlus[ℤ]), then

∫(((f+g x))^m)(((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  ∫(((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n) ExpandIntegrand[(((f+g x))^m),x]dx

Program code:

Int[(f_+g_.*x_)^m_.*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[(d1+e1*x)^p*(d2+e2*x)^p*(a+b*ArcCosh[c*x])^n,(f+g*x)^m,x],x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,g},x] && EqQ[e1-c*d1,0] && EqQ[e2+c*d2,0] && IGtQ[m,0] && IntegerQ[p+1/2] && GtQ[d1,0] && LtQ[d2,0] && IGtQ[n,0] && 
  (EqQ[n,1] && GtQ[p,-1] || GtQ[p,0] || EqQ[m,1] || EqQ[m,2] && LtQ[p,-2])

3.  ∫(((f+g x))^m) (((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  when  e1==c d1 ∧ e2==-c d2 ∧ m∈ℤ ∧ p+(1/2)∈(SuperPlus[ℤ])∧ d1>0 ∧ d2<0

1:  ∫(((f+g x))^m) (Sqrt[d1+e1 x]) (Sqrt[d2+e2 x]) (((a+b ArcCosh[c x]))^n)dx  when  e1==c d1 ∧ e2==-c d2 ∧ m∈(SuperMinus[ℤ])∧ d1>0 ∧ d2<0 ∧ n∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: If  e1==c d1 ∧ e2==-c d2 ∧ d1>0 ∧ d2<0, then ((((a+b ArcCosh[c x]))^n)/((Sqrt[d1+e1 x]) (Sqrt[d2+e2 x])))==(∂_x)((((a+b ArcCosh[c x]))^(n+1))/(b c (Sqrt[-d1 d2]) (n+1)))

Rule: If  e1==c d1 ∧ e2==-c d2 ∧ m∈(SuperMinus[ℤ])∧ d1>0 ∧ d2<0 ∧ n∈(SuperPlus[ℤ]), then

∫(((f+g x))^m)(Sqrt[d1+e1 x]) (Sqrt[d2+e2 x]) (((a+b ArcCosh[c x]))^n)dx  ⟶  
(((((f+g x))^m)(d1 d2+e1 e2 (x^2)) (((a+b ArcCosh[c x]))^(n+1)))/(b c (Sqrt[-d1 d2])(n+1)))-
(1/(b c (Sqrt[-d1 d2])(n+1)))∫(d1 d2 g m+2 e1 e2 f x+e1 e2 g (m+2) (x^2))(((f+g x))^(m-1)) (((a+b ArcCosh[c x]))^(n+1))dx

Program code:

Int[(f_+g_.*x_)^m_*Sqrt[d1_+e1_.*x_]*Sqrt[d2_+e2_.*x_]*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  (f+g*x)^m*(d1*d2+e1*e2*x^2)*(a+b*ArcCosh[c*x])^(n+1)/(b*c*Sqrt[-d1*d2]*(n+1)) - 
  1/(b*c*Sqrt[-d1*d2]*(n+1))*Int[(d1*d2*g*m+2*e1*e2*f*x+e1*e2*g*(m+2)*x^2)*(f+g*x)^(m-1)*(a+b*ArcCosh[c*x])^(n+1),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,g},x] && EqQ[e1-c*d1,0] && EqQ[e2+c*d2,0] && ILtQ[m,0] && GtQ[d1,0] && LtQ[d2,0] && IGtQ[n,0]

2:  ∫(((f+g x))^m)(((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  when  e1==c d1 ∧ e2==-c d2 ∧ m∈ℤ ∧ p+(1/2)∈(SuperPlus[ℤ])∧ d1>0 ∧ d2<0 ∧ n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  e1==c d1 ∧ e2==-c d2 ∧ m∈ℤ ∧ p+(1/2)∈(SuperPlus[ℤ])∧ d1>0 ∧ d2<0 ∧ n∈(SuperPlus[ℤ]), then

∫(((f+g x))^m)(((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  ∫(Sqrt[d1+e1 x]) (Sqrt[d2+e2 x]) (((a+b ArcCosh[c x]))^n) ExpandIntegrand[(((f+g x))^m) (((d+e (x^2)))^(p-1/2)),x]dx

Program code:

Int[(f_+g_.*x_)^m_.*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[Sqrt[d1+e1*x]*Sqrt[d2+e2*x]*(a+b*ArcCosh[c*x])^n,(f+g*x)^m*(d1+e1*x)^(p-1/2)*(d2+e2*x)^(p-1/2),x],x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,g},x] && EqQ[e1-c*d1,0] && EqQ[e2+c*d2,0] && IntegerQ[m] && IGtQ[p+1/2,0] && GtQ[d1,0] && LtQ[d2,0] && IGtQ[n,0]

3:  ∫(((f+g x))^m) (((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  when  e1==c d1 ∧ e2==-c d2 ∧ m∈(SuperMinus[ℤ])∧ p-(1/2)∈(SuperPlus[ℤ])∧ d1>0 ∧ d2<0 ∧ n∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: If  e1==c d1 ∧ e2==-c d2 ∧ d1>0 ∧ d2<0, then ((((a+b ArcCosh[c x]))^n)/((Sqrt[d1+e1 x]) (Sqrt[d2+e2 x])))==(∂_x)((((a+b ArcCosh[c x]))^(n+1))/(b c (Sqrt[-d1 d2]) (n+1)))

Rule: If  e1==c d1 ∧ e2==-c d2 ∧ m∈(SuperMinus[ℤ])∧ p-(1/2)∈(SuperPlus[ℤ])∧ d1>0 ∧ d2<0 ∧ n∈(SuperPlus[ℤ]), then

∫(((f+g x))^m) (((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  
(((((f+g x))^m) (((d1+e1 x))^(p+(1/2))) (((d2+e2 x))^(p+(1/2))) (((a+b ArcCosh[c x]))^(n+1)))/(b c (Sqrt[-d1 d2])(n+1)))-(1/(b c (Sqrt[-d1 d2])(n+1)))·
∫(((f+g x))^(m-1)) (((a+b ArcCosh[c x]))^(n+1)) ExpandIntegrand[(d1 d2 g m+e1 e2 f (2 p+1) x+e1 e2 g (m+2 p+1) (x^2)) (((d1+e1 x))^(p-(1/2))) (((d2+e2 x))^(p-(1/2))),x]dx

Program code:

Int[(f_+g_.*x_)^m_.*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  (f+g*x)^m*(d1+e1*x)^(p+1/2)*(d2+e2*x)^(p+1/2)*(a+b*ArcCosh[c*x])^(n+1)/(b*c*Sqrt[-d1*d2]*(n+1)) - 
  1/(b*c*Sqrt[-d1*d2]*(n+1))*
    Int[ExpandIntegrand[(f+g*x)^(m-1)*(a+b*ArcCosh[c*x])^(n+1),
      (d1*d2*g*m+e1*e2*f*(2*p+1)*x+e1*e2*g*(m+2*p+1)*x^2)*(d1+e1*x)^(p-1/2)*(d2+e2*x)^(p-1/2),x],x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,g},x] && EqQ[e1-c*d1,0] && EqQ[e2+c*d2,0] && ILtQ[m,0] && IGtQ[p-1/2,0] && GtQ[d1,0] && LtQ[d2,0] && IGtQ[n,0]

4.  ∫(((f+g x))^m) (((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  when  e1==c d1 ∧ e2==-c d2 ∧ m∈ℤ ∧ p-(1/2)∈(SuperMinus[ℤ])∧ d1>0 ∧ d2<0

1.  ∫(((((f+g x))^m) (((a+b ArcCosh[c x]))^n))/((Sqrt[d1+e1 x]) (Sqrt[d2+e2 x])))dx  when  e1==c d1 ∧ e2==-c d2 ∧ m∈ℤ ∧ d1>0 ∧ d2<0

1:  ∫(((((f+g x))^m) (((a+b ArcCosh[c x]))^n))/((Sqrt[d1+e1 x]) (Sqrt[d2+e2 x])))dx  when  e1==c d1 ∧ e2==-c d2 ∧ m∈(SuperPlus[ℤ]) ∧ d1>0 ∧ d2<0 ∧ n<-1

Derivation: Integration by parts

Basis: If  e1==c d1 ∧ e2==-c d2 ∧ d1>0 ∧ d2<0, then ((((a+b ArcCosh[c x]))^n)/((Sqrt[d1+e1 x]) (Sqrt[d2+e2 x])))==(∂_x)((((a+b ArcCosh[c x]))^(n+1))/(b c (Sqrt[-d1 d2]) (n+1)))

Rule: If  e1==c d1 ∧ e2==-c d2 ∧ m∈(SuperPlus[ℤ]) ∧ d1>0 ∧ d2<0 ∧ n<-1, then

∫(((((f+g x))^m) (((a+b ArcCosh[c x]))^n))/((Sqrt[d1+e1 x]) (Sqrt[d2+e2 x])))dx  ⟶  (((((f+g x))^m)(((a+b ArcCosh[c x]))^(n+1)))/(b c (Sqrt[-d1 d2])(n+1)))-((g m)/(b c (Sqrt[-d1 d2])(n+1)))∫(((f+g x))^(m-1))(((a+b ArcCosh[c x]))^(n+1))dx

Program code:

Int[(f_+g_.*x_)^m_.*(a_.+b_.*ArcCosh[c_.*x_])^n_/(Sqrt[d1_+e1_.*x_]*Sqrt[d2_+e2_.*x_]),x_Symbol] :=
  (f+g*x)^m*(a+b*ArcCosh[c*x])^(n+1)/(b*c*Sqrt[-d1*d2]*(n+1)) - 
  g*m/(b*c*Sqrt[-d1*d2]*(n+1))*Int[(f+g*x)^(m-1)*(a+b*ArcCosh[c*x])^(n+1),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,g},x] && EqQ[e1-c*d1,0] && EqQ[e2+c*d2,0] && IGtQ[m,0] && GtQ[d1,0] && LtQ[d2,0] && LtQ[n,-1]

2:  ∫(((((f+g x))^m) (((a+b ArcCosh[c x]))^n))/((Sqrt[d1+e1 x]) (Sqrt[d2+e2 x])))dx  when  e1==c d1 ∧ e2==-c d2 ∧ m∈ℤ ∧ d1>0 ∧ d2<0 ∧ (m>0 ∨ n∈(SuperPlus[ℤ]))

Derivation: Integration by substitution

Basis: If  e1==c d1 ∧ e2==-c d2 ∧ d1>0 ∧ d2<0, then ((F[x])/((Sqrt[d1+e1 x]) (Sqrt[d2+e2 x])))==(1/(c(Sqrt[-d1 d2]))) Subst[F[((Cosh[x])/c)],x,ArcCosh[c x]](∂_x)ArcCosh[c x]

Note: Mathematica 8 is unable to validate antiderivatives of ArcCosh rule when c is symbolic.

Rule: If  e1==c d1 ∧ e2==-c d2 ∧ m∈ℤ ∧ d1>0 ∧ d2<0 ∧ (m>0 ∨ n∈(SuperPlus[ℤ])), then

∫(((((f+g x))^m) (((a+b ArcCosh[c x]))^n))/((Sqrt[d1+e1 x]) (Sqrt[d2+e2 x])))dx  ⟶  (1/((c^(m+1))(Sqrt[-(Subscript[d, 1]) (Subscript[d, 2])]))) Subst[∫(((a+b x))^n)(((c f+g Cosh[x]))^m)dx,x,ArcCosh[c x]]

Program code:

Int[(f_+g_.*x_)^m_.*(a_.+b_.*ArcCosh[c_.*x_])^n_./(Sqrt[d1_+e1_.*x_]*Sqrt[d2_+e2_.*x_]),x_Symbol] :=
  1/(c^(m+1)*Sqrt[-d1*d2])*Subst[Int[(a+b*x)^n*(c*f+g*Cosh[x])^m,x],x,ArcCosh[c*x]] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,g,n},x] && EqQ[e1-c*d1,0] && EqQ[e2+c*d2,0] && IntegerQ[m] && GtQ[d1,0] && LtQ[d2,0] && (GtQ[m,0] || IGtQ[n,0])

2:  ∫(((f+g x))^m)(((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  when  e1==c d1 ∧ e2==-c d2 ∧ m∈ℤ ∧ p+(1/2)∈(SuperMinus[ℤ])∧ d1>0 ∧ d2<0 ∧ n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  e1==c d1 ∧ e2==-c d2 ∧ m∈ℤ ∧ p+(1/2)∈(SuperMinus[ℤ])∧ d1>0 ∧ d2<0 ∧ n∈(SuperPlus[ℤ]), then

∫(((f+g x))^m)(((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  
∫((((a+b ArcCosh[c x]))^n)/((Sqrt[d1+e1 x]) (Sqrt[d2+e2 x]))) ExpandIntegrand[(((f+g x))^m) (((d1+e1 x))^(p+1/2)) (((d2+e2 x))^(p+1/2)),x]dx

Program code:

Int[(f_+g_.*x_)^m_.*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcCosh[c*x])^n/(Sqrt[d1+e1*x]*Sqrt[d2+e2*x]),(f+g*x)^m*(d1+e1*x)^(p+1/2)*(d2+e2*x)^(p+1/2),x],x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,g},x] && EqQ[e1-c*d1,0] && EqQ[e2+c*d2,0] && IntegerQ[m] && ILtQ[p+1/2,0] && GtQ[d1,0] && LtQ[d2,0] && IGtQ[n,0]

2:  ∫(((f+g x))^m)(((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  when  e1==c d1 ∧ e2==-c d2 ∧ m∈ℤ ∧ p-(1/2)∈ℤ ∧ ¬(d1>0 ∧ d2<0)

Derivation: Piecewise constant extraction

Basis: If  e1==c d1 ∧ e2==-c d2, then (∂_x)(((((d1+e1 x))^p) (((d2+e2 x))^p))/((((-1+c x))^p) (((1+c x))^p)))==0

Rule: If  e1==c d1 ∧ e2==-c d2 ∧ m∈ℤ ∧ p-(1/2)∈ℤ ∧ ¬(d1>0 ∧ d2<0), then

∫(((f+g x))^m)(((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  
(((((-d1 d2))^(IntPart[p])) (((d1+e1 x))^(FracPart[p])) (((d2+e2 x))^(FracPart[p])))/((((-1+c x))^(FracPart[p])) (((1+c x))^(FracPart[p]))))∫(((f+g x))^m)(((-1+c x))^p) (((1+c x))^p)(((a+b ArcCosh[c x]))^n)dx

Program code:

Int[(f_+g_.*x_)^m_.*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  (-d1*d2)^IntPart[p]*(d1+e1*x)^FracPart[p]*(d2+e2*x)^FracPart[p]/((-1+c*x)^FracPart[p]*(1+c*x)^FracPart[p])*
    Int[(f+g*x)^m*(-1+c*x)^p*(1+c*x)^p*(a+b*ArcCosh[c*x])^n,x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,g,n},x] && EqQ[e1-c*d1,0] && EqQ[e2+c*d2,0] && IntegerQ[m] && IntegerQ[p-1/2] && Not[GtQ[d1,0] && LtQ[d2,0]]

2.  ∫Log[h (((f+g x))^m)](((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  when  e1==c d1 ∧ e2==-c d2 ∧ p-(1/2)∈ℤ

1.  ∫Log[h (((f+g x))^m)](((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  when  e1==c d1 ∧ e2==-c d2 ∧ p-(1/2)∈ℤ ∧ d1>0 ∧ d2<0

1:  ∫((Log[h (((f+g x))^m)] (((a+b ArcCosh[c x]))^n))/((Sqrt[d1+e1 x]) (Sqrt[d2+e2 x])))dx  when  e1==c d1 ∧ e2==-c d2 ∧ d1>0 ∧ d2<0 ∧ n∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: If  e1==c d1 ∧ e2==-c d2 ∧ d1>0 ∧ d2<0, then ((((a+b ArcCosh[c x]))^n)/((Sqrt[d1+e1 x]) (Sqrt[d2+e2 x])))==(∂_x)((((a+b ArcCosh[c x]))^(n+1))/(b c (Sqrt[-d1 d2]) (n+1)))

Basis: (∂_x)Log[h (((f+g x))^m)]==((g m)/(f+g x))

Note: If  n∈(SuperPlus[ℤ]), then ((((a+b ArcCosh[c x]))^(n+1))/(f+g x)) is integrable in closed-form.

Rule: If  e1==c d1 ∧ e2==-c d2 ∧ d1>0 ∧ d2<0 ∧ n∈(SuperPlus[ℤ]), then

∫((Log[h (((f+g x))^m)] (((a+b ArcCosh[c x]))^n))/((Sqrt[d1+e1 x]) (Sqrt[d2+e2 x])))dx  ⟶  ((Log[h (((f+g x))^m)](((a+b ArcCosh[c x]))^(n+1)))/(b c (Sqrt[-d1 d2]) (n+1)))-((g m)/(b c (Sqrt[-d1 d2]) (n+1)))∫((((a+b ArcCosh[c x]))^(n+1))/(f+g x))dx

Program code:

Int[Log[h_.*(f_.+g_.*x_)^m_.]*(a_.+b_.*ArcCosh[c_.*x_])^n_./(Sqrt[d1_+e1_.*x_]*Sqrt[d2_+e2_.*x_]),x_Symbol] :=
  Log[h*(f+g*x)^m]*(a+b*ArcCosh[c*x])^(n+1)/(b*c*Sqrt[-d1*d2]*(n+1)) - 
  g*m/(b*c*Sqrt[-d1*d2]*(n+1))*Int[(a+b*ArcCosh[c*x])^(n+1)/(f+g*x),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,g,h,m},x] && EqQ[e1-c*d1,0] && EqQ[e2+c*d2,0] && GtQ[d1,0] && LtQ[d2,0] && IGtQ[n,0]

2:  ∫Log[h (((f+g x))^m)] (((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  when  e1==c d1 ∧ e2==-c d2 ∧ p-(1/2)∈ℤ ∧ ¬(d1>0 ∧ d2<0)

Derivation: Piecewise constant extraction

Basis: If  e1==c d1 ∧ e2==-c d2, then (∂_x)(((((d1+e1 x))^p) (((d2+e2 x))^p))/((((-1+c x))^p) (((1+c x))^p)))==0

Rule: If  e1==c d1 ∧ e2==-c d2 ∧ p-(1/2)∈ℤ ∧ ¬(d1>0 ∧ d2<0), then

∫Log[h (((f+g x))^m)] (((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  
(((((-d1 d2))^(IntPart[p])) (((d1+e1 x))^(FracPart[p])) (((d2+e2 x))^(FracPart[p])))/((((-1+c x))^(FracPart[p])) (((1+c x))^(FracPart[p]))))∫Log[h (((f+g x))^m)] (((-1+c x))^p) (((1+c x))^p) (((a+b ArcCosh[c x]))^n)dx

Program code:

Int[Log[h_.*(f_.+g_.*x_)^m_.]*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  (-d1*d2)^IntPart[p]*(d1+e1*x)^FracPart[p]*(d2+e2*x)^FracPart[p]/((-1+c*x)^FracPart[p]*(1+c*x)^FracPart[p])*
    Int[Log[h*(f+g*x)^m]*(-1+c*x)^p*(1+c*x)^p*(a+b*ArcCosh[c*x])^n,x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,g,h,m,n},x] && EqQ[e1-c*d1,0] && EqQ[e2+c*d2,0] && IntegerQ[p-1/2] && Not[GtQ[d1,0] && LtQ[d2,0]]

6.  ∫(((d+e x))^m)(((f+g x))^m)(((a+b ArcCosh[c x]))^n)dx

1:  ∫(((d+e x))^m)(((f+g x))^m) (a+b ArcCosh[c x])dx  when  m+(1/2)∈(SuperMinus[ℤ])

Derivation: Integration by parts

Basis: (∂_x)(a+b ArcCosh[c x])==((b c)/((Sqrt[-1+c x]) (Sqrt[1+c x])))

Rule: If  m+(1/2)∈(SuperMinus[ℤ]), let u->∫(((d+e x))^m)(((f+g x))^m)dx, then

∫(((d+e x))^m)(((f+g x))^m) (a+b ArcCosh[c x])dx  ⟶  u (a+b ArcCosh[c x])-b c∫(u/((Sqrt[-1+c x]) (Sqrt[1+c x])))dx

Program code:

Int[(d_+e_.*x_)^m_*(f_+g_.*x_)^m_*(a_.+b_.*ArcCosh[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(d+e*x)^m*(f+g*x)^m,x]},  
  Dist[a+b*ArcCosh[c*x],u,x] - b*c*Int[Dist[1/(Sqrt[-1+c*x]*Sqrt[1+c*x]),u,x],x]] /;
FreeQ[{a,b,c,d,e,f,g},x] && ILtQ[m+1/2,0]

2:  ∫(((d+e x))^m)(((f+g x))^m)(((a+b ArcCosh[c x]))^n)dx  when  m∈ℤ

Derivation: Algebraic expansion

Rule: If  m∈ℤ, then

∫(((d+e x))^m)(((f+g x))^m)(((a+b ArcCosh[c x]))^n)dx  ⟶  ∫(((a+b ArcCosh[c x]))^n) ExpandIntegrand[(((d+e x))^m)(((f+g x))^m),x]dx

Program code:

Int[(d_+e_.*x_)^m_.*(f_+g_.*x_)^m_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcCosh[c*x])^n,(d+e*x)^m*(f+g*x)^m,x],x] /;
FreeQ[{a,b,c,d,e,f,g,n},x] && IntegerQ[m]

7:  ∫u (a+b ArcCosh[c x])dx  when  ∫udx  is free of inverse functions

Derivation: Integration by parts

Basis: (∂_x)(a+b ArcCosh[c x])==((b c)/((Sqrt[-1+c x]) (Sqrt[1+c x])))

Rule: Let  v->∫udx, if v is free of inverse functions, then

∫u (a+b ArcCosh[c x])dx  ⟶  v (a+b ArcCosh[c x])-b c∫(v/((Sqrt[-1+c x]) (Sqrt[1+c x])))dx
  ⟶  v (a+b ArcCosh[c x])-((b c(Sqrt[1-(c^2) (x^2)]))/((Sqrt[-1+c x]) (Sqrt[1+c x])))∫(v/(Sqrt[1-(c^2) (x^2)]))dx

Program code:

Int[u_*(a_.+b_.*ArcCosh[c_.*x_]),x_Symbol] :=
  With[{v=IntHide[u,x]},  
  Dist[a+b*ArcCosh[c*x],v,x] - 
  b*c*Sqrt[1-c^2*x^2]/(Sqrt[-1+c*x]*Sqrt[1+c*x])*Int[SimplifyIntegrand[v/Sqrt[1-c^2*x^2],x],x] /;
 InverseFunctionFreeQ[v,x]] /;
FreeQ[{a,b,c},x]

8.  ∫(Subscript[P, x])F[(((d1+e1 x))^p) (((d2+e2 x))^p)](((a+b ArcCosh[c x]))^n)dx  when  e1==c d1 ∧ e2==-c d2 ∧ p-(1/2)∈ℤ

1:  ∫(Subscript[P, x]) (((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  when  e1==c d1 ∧ e2==-c d2 ∧ p-(1/2)∈ℤ

Derivation: Algebraic expansion

Rule: If  e1==c d1 ∧ e2==-c d2 ∧ p-(1/2)∈ℤ, then

∫(Subscript[P, x]) (((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  ∫ExpandIntegrand[(Subscript[P, x]) (((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n),x]dx

Program code:

Int[Px_*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_,x_Symbol] :=
  With[{u=ExpandIntegrand[Px*(d1+e1*x)^p*(d2+e2*x)^p*(a+b*ArcCosh[c*x])^n,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{a,b,c,d1,e1,d2,e2,n},x] && PolyQ[Px,x] && EqQ[e1-c*d1,0] && EqQ[e2+c*d2,0] && IntegerQ[p-1/2]

2:  ∫(Subscript[P, x])(((f+g(((d1+e1 x))^p) (((d2+e2 x))^p)))^m)(((a+b ArcCosh[c x]))^n)dx  when  e1==c d1 ∧ e2==-c d2 ∧ p+(1/2)∈(SuperPlus[ℤ])∧ (m|n)∈ℤ

Derivation: Algebraic expansion

Rule: If  e1==c d1 ∧ e2==-c d2 ∧ p+(1/2)∈(SuperPlus[ℤ])∧ (m|n)∈ℤ, then

∫(Subscript[P, x])(((f+g(((d1+e1 x))^p) (((d2+e2 x))^p)))^m)(((a+b ArcCosh[c x]))^n)dx  ⟶  ∫ExpandIntegrand[(Subscript[P, x])(((f+g(((d1+e1 x))^p) (((d2+e2 x))^p)))^m)(((a+b ArcCosh[c x]))^n),x]dx

Program code:

Int[Px_.*(f_+g_.*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_)^m_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  With[{u=ExpandIntegrand[Px*(f+g*(d1+e1*x)^p*(d2+e2*x)^p)^m*(a+b*ArcCosh[c*x])^n,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,g},x] && PolyQ[Px,x] && EqQ[e1-c*d1,0] && EqQ[e2+c*d2,0] && IGtQ[p+1/2,0] && IntegersQ[m,n]

9.  ∫(Subscript[RF, x])u(((a+b ArcCosh[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

1.  ∫(Subscript[RF, x]) (((a+b ArcCosh[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

1:  ∫(Subscript[RF, x])((ArcCosh[c x])^n)dx  when  n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  n∈(SuperPlus[ℤ]), then

∫(Subscript[RF, x])((ArcCosh[c x])^n)dx  ⟶  ∫((ArcCosh[c x])^n)ExpandIntegrand[(Subscript[RF, x]),x]dx

Program code:

Int[RFx_*ArcCosh[c_.*x_]^n_.,x_Symbol] :=
  With[{u=ExpandIntegrand[ArcCosh[c*x]^n,RFx,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[c,x] && RationalFunctionQ[RFx,x] && IGtQ[n,0]

2:  ∫(Subscript[RF, x])(((a+b ArcCosh[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  n∈(SuperPlus[ℤ]), then

∫(Subscript[RF, x])(((a+b ArcCosh[c x]))^n)dx  ⟶  ∫ExpandIntegrand[(Subscript[RF, x])(((a+b ArcCosh[c x]))^n),x]dx

Program code:

Int[RFx_*(a_+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[RFx*(a+b*ArcCosh[c*x])^n,x],x] /;
FreeQ[{a,b,c},x] && RationalFunctionQ[RFx,x] && IGtQ[n,0]

2.  ∫(Subscript[RF, x]) (((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ e1==c d1 ∧ e2==-c d2 ∧ p-(1/2)∈ℤ

1:  ∫(Subscript[RF, x]) (((d1+e1 x))^p) (((d2+e2 x))^p) ((ArcCosh[c x])^n)dx  when  n∈(SuperPlus[ℤ])∧ e1==c d1 ∧ e2==-c d2 ∧ p-(1/2)∈ℤ

Derivation: Algebraic expansion

Rule: If  n∈(SuperPlus[ℤ])∧ e1==c d1 ∧ e2==-c d2 ∧ p-(1/2)∈ℤ, then

∫(Subscript[RF, x])(((d1+e1 x))^p) (((d2+e2 x))^p)((ArcCosh[c x])^n)dx  ⟶  ∫(((d1+e1 x))^p) (((d2+e2 x))^p)((ArcCosh[c x])^n)ExpandIntegrand[(Subscript[RF, x]),x]dx

Program code:

Int[RFx_*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*ArcCosh[c_.*x_]^n_.,x_Symbol] :=
  With[{u=ExpandIntegrand[(d1+e1*x)^p*(d2+e2*x)^p*ArcCosh[c*x]^n,RFx,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{c,d1,e1,d2,e2},x] && RationalFunctionQ[RFx,x] && IGtQ[n,0] && EqQ[e1-c*d1,0] && EqQ[e2+c*d2,0] && IntegerQ[p-1/2]

2:  ∫(Subscript[RF, x]) (((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ e1==c d1 ∧ e2==-c d2 ∧ p-(1/2)∈ℤ

Derivation: Algebraic expansion

Rule: If  n∈(SuperPlus[ℤ])∧ e1==c d1 ∧ e2==-c d2 ∧ p-(1/2)∈ℤ, then

∫(Subscript[RF, x])(((d1+e1 x))^p) (((d2+e2 x))^p)(((a+b ArcCosh[c x]))^n)dx  ⟶  ∫(((d1+e1 x))^p) (((d2+e2 x))^p)ExpandIntegrand[(Subscript[RF, x])(((a+b ArcCosh[c x]))^n),x]dx

Program code:

Int[RFx_*(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[(d1+e1*x)^p*(d2+e2*x)^p,RFx*(a+b*ArcCosh[c*x])^n,x],x] /;
FreeQ[{a,b,c,d1,e1,d2,e2},x] && RationalFunctionQ[RFx,x] && IGtQ[n,0] && EqQ[e1-c*d1,0] && EqQ[e2+c*d2,0] && IntegerQ[p-1/2]

U:  ∫u(((a+b ArcCosh[c x]))^n)dx

Rule:

∫u(((a+b ArcCosh[c x]))^n)dx  ⟶  ∫u(((a+b ArcCosh[c x]))^n)dx

Program code:

Int[u_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  Unintegrable[u*(a+b*ArcCosh[c*x])^n,x] /;
FreeQ[{a,b,c,n},x]